#### ADDRESS

[Syntax](Syntax.docx):

ADDRESS ( row-number , col-number [ , [ ref-type ] [ , [ A1-ref-style-flag ]
[ , sheet-name ] ] ] )

Description: Creates a [cell](cell.docx) address, given the specified [row](row.docx) and column numbers.

Arguments:

|  |  |  |
| --- | --- | --- |
| Name | Type | Description |
| row-number | number | The number of the row. |
| col-number | number | The number of the column. |
| ref-type | number | The type of [reference](reference.docx) to return, as follows:

|  |  |
| --- | --- |
| Value | Type of Reference Returned |
| 1 or omitted | Absolute [row](row.docx) and column |
| 2 | Absolute row; relative column |
| 3 | Relative row; absolute column |
| 4 | Relative [row](row.docx) and column |

 |
| A1-ref-style-flag | logical | The style of the reference. If [TRUE](TRUE.docx) or omitted, an A1-style [reference](reference.docx) (§) is returned; otherwise, an R1C1-style [reference](reference.docx) (§) is returned. |
| sheet-name | [text](text.docx) | The name of the [worksheet](worksheet.docx) to be used. If omitted, no [sheet](sheet.docx) name is used. |

Return Type and Value: text – A [cell](cell.docx) address, given the specified [row](row.docx) and column numbers.

However, if

* row-number or col-number < 1, #NUM! is returned.
* ref-type is outside the range 1–4, #NUM! is returned.

 [Example:

In A1-reference style mode:

ADDRESS(5,7,1) results in $G$5
ADDRESS(5,7,2) results in G$5
ADDRESS(5,7,3) results in $G5
ADDRESS(5,7,4) results in G5
ADDRESS(5,7,,,"Sheet1") results in Sheet1!$G$5

In R1C1-reference style mode:

ADDRESS(5,7,1,FALSE) results in R5C7
ADDRESS(5,7,2,FALSE) results in R5C[7]
ADDRESS(5,7,3,FALSE) results in R[5]C7
ADDRESS(5,7,4,FALSE) results in R[5]C[7]

end example]